:local Config {{name="addr1";addr="::0:0:0:1"}}
foreach C in=$Config do={
 :local IdAddr [/ipv6 address find comment=($C->"name")]
 :local Interface [/ipv6 address get $IdAddr interface]
 :local Disabled [/ipv6 address get $IdAddr disabled]
 :local IdPrefix [/ipv6 nd prefix find interface=$Interface valid-lifetime="0s"]
 :local OldAddr [/ipv6 address get $IdAddr address]
 :local OldPrefix (([:toip6 [:pick $OldAddr 0 [:find $OldAddr "/"]]] & ffff:ffff:ffff:ffff::)."/64")
#### pls remove extra spaces after the = sign
 :if ($"pd-valid"=  1) do={
   :log info "pd-valid is 1"
   :local NewAddr (([:toip6 [:pick $"pd-prefix" 0 [:find $"pd-prefix" "/"]]] | [:toip6 ($C->"addr")])."/64")
   :local NewPrefix (([:toip6 [:pick $NewAddr 0 [:find $NewAddr "/"]]] & ffff:ffff:ffff:ffff::)."/64")
   :if ($OldAddr != $NewAddr || $Disabled = true) do={
     :if ($OldPrefix = $NewPrefix)  do={
       /ipv6 nd prefix set $IdPrefix disabled=yes
       :delay 1s
     }
     :log info ($Interface.": new prefix: ".$NewPrefix)
     /ipv6 address set $IdAddr address=$NewAddr disabled=no
     :delay 1s
     :if ($OldPrefix != $NewPrefix && $OldPrefix != ::/64)  do={
       /ipv6 nd prefix set $IdPrefix prefix=$OldPrefix disabled=no
       :log info ($Interface.": expired prefix: ".$OldPrefix)
       :delay 1s
     }
   }
 } else={
   /ipv6 address set $IdAddr disabled=yes
   :delay 1s
   /ipv6 nd prefix set $IdPrefix prefix=$OldPrefix disabled=no
   :log info ($Interface.": expired prefix: ".$OldPrefix)
   :delay 1s
 }
}