Welcome Guest ( Log In | Register )

Outline · [ Standard ] · Linear+

Hardware Problem with Seagate 750GB HDD

views
     
TS4lt4ir
post May 21 2008, 07:29 PM, updated 16y ago

{--} 7
******
Senior Member
1,397 posts

Joined: Sep 2006
Hi all, would appreciate your feedback/help as regards to the following issue.

Recently my father purchased a couple of 750GB Seagate HDD. One he installed inside his PC and the other in an external drive connected to the PC. Both are not connected to the mobo by SATA, because his mobo has not enough SATA ports.

Anyway, the problem is...after he has installed these HDD, the PC runs fine, as per normal, BUT...when playing a movie, the movie will experience a lot of jerkiness and the movie is also slowed down, almost as if it's in slow-motion. Plus, the movie's sounds will be quite high-pitched and jerky, kinda like Alvin the Chipmunk's voice. Haha. He went back to Lowyat to get the HDD replaced, thinking it was defective (one of the HDD did kaput shortly after that), but after get replacement unit also the problem persists.

Any ideas as to what's the cause? Maybe the power supply is not providing enough juice? Or is it due to some other thing?
MX510
post May 21 2008, 07:34 PM

Love Me Sin Hate Me Sinner
*******
Senior Member
4,032 posts

Joined: Aug 2005
From: Earth



Try upgrading your power supply it need more power :-)
netmatrix
post May 21 2008, 07:37 PM

The machine... it sees everything.
*******
Senior Member
6,491 posts

Joined: Jan 2003
From: Zion


QUOTE
Recently my father purchased a couple of 750GB Seagate HDD. One he installed inside his PC and the other in an external drive connected to the PC. Both are not connected to the mobo by SATA, because his mobo has not enough SATA ports


You mean one of the HDD is installed in PATA mode? If that is the case, the PATA mode HDD is experiencing bottleneck. You can have a 7200rpm drive. But seriously, it should run in SATA mode. Whatever hdd that is using the other SATA ports should be junked. Also i don't think there is a 750G PATA drive. It does come in SATA though. Unless you run it off a SATA card?
SUSHybz
post May 21 2008, 07:46 PM

Enthusiast
*****
Senior Member
846 posts

Joined: Apr 2008
It could be your media codec problem also ...
icp
post May 21 2008, 07:50 PM

Casual
***
Junior Member
478 posts

Joined: Nov 2007
From: b.b.bangi



^i second that..myb got codec problem..i use Media Player Classic,works fine
TS4lt4ir
post May 21 2008, 08:04 PM

{--} 7
******
Senior Member
1,397 posts

Joined: Sep 2006
Hybz, I doubt it's a codec problem...as the movies were playing fine as per normal before the HDD were installed.

Netmatrix, the PATA bottleneck might be the issue. I'll have to check in again with my father to check if that is the case. As it is, I'm not entirely sure how he hooked up the HDD.

Btw, ty all for your prompt replies =)
WebWalker
post May 21 2008, 08:51 PM

Computer Geek
********
All Stars
12,851 posts

Joined: May 2005
From: Puchong, Selangor



Make sure the internal IDE HD that you install to your system has been DMA enable.

Without DMA (Direct Memory Access) enable, the drive will be very slow

DMA - http://en.wikipedia.org/wiki/Direct_memory_access
d3x
post May 22 2008, 01:18 AM

The atheist with the GoogleBrain™ Plugin.
******
Senior Member
1,540 posts

Joined: Jan 2003
From: Alexandria



You could also try forcing the drives to run in SATA 1.5gbps mode (SATA/150). Some old SATA controllers doesn't support auto-negotiations and this might cause slowdowns or even errors with the drives.

http://seagate.custhelp.com/cgi-bin/seagat...p?p_faqid=3178&

This post has been edited by d3x: May 22 2008, 01:23 AM
TS4lt4ir
post Jun 15 2008, 11:58 PM

{--} 7
******
Senior Member
1,397 posts

Joined: Sep 2006
How to enable DMA? i can't find it by right clicking and click properties =(
eclectice
post Jun 16 2008, 12:41 AM

Look at all my stars!!
*******
Senior Member
2,708 posts

Joined: Mar 2008
QUOTE(dani_irwan @ Jun 15 2008, 11:58 PM)
How to enable DMA? i can't find it by right clicking and click properties =(
*
This example if you are using an IDE channel (P-ATA type). You need to access Device Manager and look in the tree view for IDE channels. Open its Properties and enable Auto Detection option to let Windows to choose the supported DMA mode.

Attached Image

However, some ATA devices are so stubborn and crazy sometimes, causing Windows to drop to a lower mode (like PIO mode). This normally happens with CD/DVD drives which is causing slow access speed and jerkiness. There is a script below which will force Windows to recognize the ATA devices in DMA mode.

http://winhlp.com/node/10

Save this Visual Basic Script (VBS) as resetdma.vbs
CODE

' Visual Basic Script program to reset the DMA status of all ATA drives

' Copyright © 2006 Hans-Georg Michna

' Version 2007-04-04

' Works in Windows XP, probably also in Windows 2000 and NT.
' Does no harm if Windows version is incompatible.

If MsgBox("This program will now reset the DMA status of all ATA drives with Windows drivers." _
 & vbNewline & "Windows will redetect the status after the next reboot, therefore this procedure" _
 & vbNewline & "should be harmless.", _
   vbOkCancel, "Program start message") _
 = vbOk Then

RegPath = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Class\{4D36E96A-E325-11CE-BFC1-

08002BE10318}\"
ValueName1Master = "MasterIdDataChecksum"
ValueName1Slave = "SlaveIdDataChecksum"
ValueName2Master = "UserMasterDeviceTimingModeAllowed"
ValueName2Slave = "UserSlaveDeviceTimingModeAllowed"
ValueName3 = "ResetErrorCountersOnSuccess"
MessageText = "The following ATA channels have been reset:"
MessageTextLen0 = Len(MessageText)
ConsecutiveMisses = 0
Set WshShell = WScript.CreateObject("WScript.Shell")

For i = 0 to 999
 RegSubPath = Right("000" & i, 4) & "\"

 ' Master

 Err.Clear
 On Error Resume Next
 WshShell.RegRead RegPath & RegSubPath & ValueName1Master
 errMaster = Err.Number
 On Error Goto 0
 If errMaster = 0 Then
   On Error Resume Next
   WshShell.RegDelete RegPath & RegSubPath & ValueName1Master
   WshShell.RegDelete RegPath & RegSubPath & ValueName2Master
   On Error Goto 0
   MessageText = MessageText & vbNewLine & "Master"
 End If

 ' Slave

 Err.Clear
 On Error Resume Next
 WshShell.RegRead RegPath & RegSubPath & ValueName1Slave
 errSlave = Err.Number
 On Error Goto 0
 If errSlave = 0 Then
   On Error Resume Next
   WshShell.RegDelete RegPath & RegSubPath & ValueName1Slave
   WshShell.RegDelete RegPath & RegSubPath & ValueName2Slave
   On Error Goto 0
   If errMaster = 0 Then
     MessageText = MessageText & " and "
   Else
     MessageText = MessageText & vbNewLine
   End If
   MessageText = MessageText & "Slave"
 End If

 If errMaster = 0 Or errSlave = 0 Then
   On Error Resume Next
   WshShell.RegWrite RegPath & RegSubPath & ValueName3, 1, "REG_DWORD"
   On Error Goto 0
   ChannelName = "unnamed channel " & Left(RegSubPath, 4)
   On Error Resume Next
   ChannelName = WshShell.RegRead(RegPath & RegSubPath & "DriverDesc")
   On Error Goto 0
   MessageText = MessageText & " of " & ChannelName & ";"
   ConsecutiveMisses = 0
 Else
   ConsecutiveMisses = ConsecutiveMisses + 1
   If ConsecutiveMisses >= 32 Then Exit For ' Don't search unnecessarily long.
 End If
Next ' i

If Len(MessageText) <= MessageTextLen0 Then
 MessageText = "No resettable ATA channels with Windows drivers found. Nothing changed."
Else
 MessageText = MessageText & vbNewline _
   & "Please reboot now to reset and redetect the DMA status."
End If

MsgBox MessageText, vbOkOnly, "Program finished normally"

End If ' MsgBox(...) = vbOk

' End of Visual Basic Script program



This post has been edited by eclectice: Jun 16 2008, 12:48 AM

 

Change to:
| Lo-Fi Version
0.0143sec    0.25    6 queries    GZIP Disabled
Time is now: 29th March 2024 - 09:12 PM